<form id="37lca"><noframes id="37lca">
<sub id="37lca"><progress id="37lca"></progress></sub>
  • <sub id="37lca"><xmp id="37lca">
         
     

    AD板ActiveX控件ADCardX使用说明

    第一节 VB下控件使用方法

    一、使用简介

    本控件可在Windows 95/98下支持ActiveX的任何开发环境中使用,如Visual Baisc、 Delphi、 C++Builder、Visual C++等。它把对北京瑞博华控制技术有限公司开发的各类AD采集板的控制命令以用户易于理解和使用的方式提供给用户,使用户以简单、高效地方式操作AD板,而不用处理底层的硬件细节。而且,本控件可支持本公司的系列AD板,即同一个控件和同一套用户程序可支持不同的AD板。

    本控件使用方式极为简单,现以VB开发环境为例说明其使用方法:

    首先,在VB环境中先引用此控件(在Windows 95系统目录下,文件名ADCardX.OCX,控件类型为ADCardX);

    其次,在用户的Form中,放置此控件,缺省控件名为ADCardX1,它的界面比较简单,直接显示本机器中所安装的AD采集板的名称;

    然后,可在属性窗口中设置AD板的各种属性,如I/O基地址、采样频率等,或在程序中直接用代码设置各属性。

    然后,在程序中操作AD板的过程如下:

    第一步先要调用Initial()方法初始化AD板,返回值告诉用户初始化是否成功(=0即失败)。

    第二步要调用StartIntr()方法或StartSnapshot()方法让AD板开始采样;

    第三步,为了得到采样结果,调用方法GetADResult()或GetADResultRecent()或GetSnapshot(),就直接把采样结果存放在用户指定的数组中,然后用户可以直接在此数组中使用AD采样结果了,如存盘、图形显示或进行别的处理。

    第四步,AD采样结束时,调用StopIntr()或StopSnapshot()方法使AD板停止工作。

    最后,需要说明的是本控件有两种工作方式:

    一种是多缓冲区方式,用StartIntr()方法启动。此时系统(驱动程序)内部开有NumInnerBuf个缓冲区,每个缓冲区可存放NumChn个通道、每通道SampPerChn个AD采样结果。AD采集的结果顺序存放在各缓冲区中,GetADResult()方法就顺序地取出(最先)一个放满采样结果的缓冲区的内容(进行过此操作后此缓冲区又可接收新的采集结果),而GetADResultRecent()方法直接取最后(新)一个缓冲区的内容(进行过此操作后所有缓冲区又可重新接收新的采集结果)。在这种方式下,存放有AD采集结果的缓冲区数目可用方法ResultBuf()进行查询,而且,在设置属性EnableNotify为True时,每一个缓冲区满时会给用户程序发送事件Notify(),用户可在这个事件响应函数中进行取AD缓冲区的工作。此方式用StopIntr()停止。若没有及时从缓冲区取采样结果,而使所有缓冲区都满时,此后AD采样结果就将丢失,直到有缓冲区被GetADResult()或GetADResultRecent()释放、可存放新的采样结果为止。此工作方式适宜于连续记录AD采集结果。连续两次成功地GetADResult()取得的AD结果在时间上不会重叠,之间是否丢失采样结果,要看返回结果的序列号(结果数组的第一个值,为无符号短整数)是否递增加一(注意,0xFFFF加一后会变成0)。只增一,说明两缓冲区在时间上是连续的。在采样率较低时,通过多缓冲区方式,有可能连续地记录、处理、保存长时间的AD结果。

    另一工作方式为单缓冲区方式,用StartSnapshot()方法启动,它始终不断地往缓冲区中存放AD结果,缓冲区大小为NumChn个通道,每通道SampPerChn个点。方法GetSnapshot()从此缓冲区中得到所有通道、最新指定个点(点数在方法的参数中指定)的采集结果(的快照),这时EnableNotify属性值一般应置为无效。此工作方式由命令StopSnapshot()终止。此工作方式适宜于示波器方式,可随时得到最新的采集结果(的快照)。但两次GetSanpshot()取得的结果在时间上可能有重叠或丢失,相对时间关系不能确定,或者通过函数GetSnapshot(ByRef ADBuf as Integer, ByVal SampPerChn0 as Long, ByRef SampPtr as Long)返回的SampPtr值和返回的ADBuf第一个元素所代表的系列号来求出。

    二、属性和方法说明

    重要的属性含义如下,按名称、类型、含义进行介绍:

    IOBase: Integer。指定AD板I/O基地址。

    IRQNum: Integer。指定AD板占用的IRQ值(0-15)。

    PhysAddr: Long。指定AD板占用的RAM地址。

    DMAChn:Integer。指定AD板使用的DMA通道号。

    NumInnerBuf: Integer。指定多缓冲区方式下内部缓冲区个数。

    SampPerChn: Long。指定每个缓冲区内可存放的每通道采样点数。

    BegChn: Integer。在单通道采集方式下,指定采集的通道号;多通道方式下,指定起始通道号;在既有模拟通道又有开关量通道的板上,BegChn表示模拟通道道第BegChn及之后就存放开关量通道的值。注:有些AD板BegChn有定义,有些AD板可为任意值而无任何作用。

    NumChn: Integer。指定要采集的总通道数。

    FrqSamp: Long。指定的名义采样频率。而每通道实际采样频率可通过CHnFrq方法获得。

    FrqFilter: Long。指定内部滤波器截止频率。对有些AD板此参数无作用。

    AmpGain:Integer。指定板上程控放大器的增益。一般可为1,2,4,8,10,100,1000。对有些AD板此参数无作用。

    EnableNotify: Boolean(True or False)。指定多缓冲区方式或单缓冲区方式下是否触发事件Notify。

    NofityLength:Long。指定单缓冲区方式下各通道采集NotifyLength个数时触发一个Notify事件。注:多缓冲区方式下,每缓冲区满就触发一个Notify事件,只要EnableNotify=True。

    ADCardName: String(只读, 并显示在控件本身上)。返回AD板类型(名称)。

    ResultBuf: Integer(只读)。返回已有采集结果的缓冲区数目。仅多缓冲区方式下有意义。

    Visible: Integer(better set to False)。指定控件是否可件。为美观起见一般设为不可见。

    MaxChn: Long(只读)。返回当前采集板支持的最多通道数(含开关量通道,每16个开关量占一个模拟量的内存地址)。

    MaxBinChn:Long(只读)。返回当前采集板支持的最多开关通道数。

    VZero: Single(只读)。返回当前采集板采集结果的格式:在16位无符号短整数表示的AD值中,电平0对应的值。

    VMax: Single(只读) 。返回当前采集板采集结果的格式:在16位无符号短整数表示的AD值中,最高电平(+5V)对应的值。

    注:由上可知:对AD采集结果ADBuf(?),它实际采用偏移二进制编码,它对应的实际电压为(单位:V):

    (ADBuf(?)-VZero)/(VMax-VZero)*5

    但由于VB不支持无符号整数(只能按有符号整数对待),对16位AD芯片(VZero=32768., VMax=65535.),要得到电压值,需用如下公式:

    If (ADBuf(1) > 0) Then

    V = (ADBuf(1) - VZero) / (VMax - VZero) * 5

    Else

    V = (65536 + ADBuf(1) - VZero) / (VMax - VZero) * 5)

    End If

    重要的方法:

    ChannelFrq(ByVal NumChn As Long, ByVal FrqSamp As Long) as Single:返回值的含义为:若属性NumChn(仅指模拟通道数目)和FrqSamp置为本方法指定的参数时每通道的实际采样率(单位:Hz)。

    Initial() as integer:初始化AD板。AD板存在,且属性IOBase、IRQNum、PhysAddr正确时返回常数ADCard_Success,否则返回ADCard_Error(=0)。

    StartIntr() as Long:启动多缓冲区工作方式。成功时返回每缓冲区的大小(字节数),这时,用GetADResult()或GetADResultRecent()时用到的缓冲区大小应大于或等于此值(字节数)。失败时返回0。

    StopIntr() as Integer:停止多缓冲区工作方式。

    StartSnapshot() as Integer:启动单缓冲区工作方式。成功时返回内部缓冲区的大小(字节数)。失败时返回0。

    StopSnapshot() as Integer:停止单缓冲区工作方式。

    ResultBuf() as Integer:返回多缓冲区方式下已有采集结果的缓冲区数目。

    GetADResult(ByRef ADBuf as Integer) as Integer:在多缓冲区方式下把最先的一个有采集结果的缓冲区内容拷贝到用户数组ADBuf中。并释放当前缓冲区。

    这时用户数组尺寸要求大于SampPerChn*NumChn+1个短整数。

    GetADResultRecent(ByRef ADBuf as Integer) as integer:在多缓冲区方式下把最新的一个有采集结果的缓冲区内容拷贝到用户数组ADBuf中,并释放所有内部缓冲区。

    这时用户数组尺寸要求大于或等于SampPerChn*NumChn+1个短整数。

    GetSnapshot(ByRef ADBuf as Integer, ByVal SampPerChn0 as Long, ByRef SampPtr as Long) as Integer:

    在单缓冲区方式下把最新的采集结果(仅SampPerChn0个点、NumChn个通道)拷贝到用户数组ADBuf中。最新数据在内部缓冲区中的位置返回在SampPtr中,它的范围为0~SampPerChn-1,而内部缓冲区已被覆盖过几次,这值返回在数组ADBuf的第一个短整数中,即SeqNo中,用户可由这两个参数确定两次GetSnapshot取的结果的相对时间关系。要求SampPerChn0<SampPerChn。

    这时用户数组尺寸要求大于或等于SampPerChn0*NumChn+3个短整数。

    IOCtl(ByVal InSize as Long, ByVal InBuff as String, ByVal OutSize as Long, ByVal OutBuff as String) as Long: 和AD板专用数据交换接口。

    IOCtlByte(ByVal InSize as Long, ByRef InBuff as Byte, ByVal OutSize as Long, ByRef OutBuff as Byte) as Long: 和AD板专用数据交换接口的另一种参数类型。

    InportB(ByVal Port as Integer) as Integer:单字节端口读。辅助工具接口函数。

    Inport(ByVal Port as Integer) as Integer:单字端口读。辅助工具接口函数。

    InportDW(ByVal Port as Integer) as Long:双字端口读。辅助工具接口函数。

    OutportB(ByVal Port as Integer, ByVal Value as Integer):单字节端口写。辅助工具接口函数。

    Outport(ByVal Port as Integer, ByVal Value as Integer):单字端口写。辅助工具接口函数。

    OutportDW(ByVal Port as Integer, ByVal Value as Long):双字端口写。辅助工具接口函数。

    三、AD缓冲区格式说明

    返回AD结果格式说明:

    方法GetADResult()、GetADResultRecent()、GetSnapshot()把AD采集结果拷贝在用户数组ADBuf()中,ADBuf的格式定义为:

    Dim ADBuf(NumChn*SampPerChn+1) as Integer

    则: ADBuf(0)为此次结果的序列号:在多缓冲区方式下,每个缓冲区的序列号按采集时间先后顺序增一,若缓冲区满而丢失数据时此值会增加以表示丢失了多少缓冲区;在单缓冲区方式下,表示此次快照是系统内部缓冲区被覆盖(填满)多少此时的结果。此值是按无符号短整数递增的,在65535(=0xffff)后会反转为0的。

    ADBuf(1至NumChn*SampPerChn)顺序存放各通道、各时刻的采样值。第n通道(n=0至NumChn-1)、第m时刻(m=1至SampPerChn)就存放在数组单元ADBuf((m-1)*NumChn+n+1)中,即ADBuf(1)存放第0通道第1时刻的值,ADBuf(2)存放第1通道第1时刻值,......,ADBuf(NumChn)存放第NumChn-1通道第1时刻的值,ADBuf(NumChn+1)存放第0通道第2时刻的值,......。对12位AD板,采样结果为偏移二进制编码,即:0表示最低电压值(如-5V),2048(=0x800)表示0电压,4095(=0xfff)表示最高电压(如+5V)。具体电压值可由属性VZero和VMax转换出。

    若AD板既支持模拟量,又支持开关量,则在等价的NumChn个总通道中,通道0至BegChn-1为常规的模拟量,通道BegChn至NumChn-1为组合的开关量通道,每16个开关量通道占1个模拟量通道的缓冲区(即每模拟通道占1位,且通道0占短整数的bit 0,通道15占短整数的bit15,而每模拟通道占16位(无符号短整数))

    四、杂类说明:

    1. 重要的事件:

    Notify(): 在多缓冲区方式下,每一个内部缓冲区填满采集结果时调用一次此事件。

    2. 重要的常数定义:

    ADCard_Error = 0

    ADCard_Success = 1

    3. 注意事项:

    此控件需要在\Windows\System目录下的 ADCard.DLL和相应的VxD驱动程序支持。

    五、简单的VB示例

    一个简单的使用示例如下(VB5):

    建立一个窗体(Form),在其上定义几个控件:Label1, Label2, ADCardX1,Command1,Timer1

    拷贝如下代码,就建立起一个简单但完整的AD采集程序:(点击命令按钮就开始采样,再点击就停止。采样结果显示在Label1(表示缓冲区序列号)和Label2(表示第iChn通道、第iSamp点的采样值)上)。注意,在Form_Load中设置WorkMode = 0 表示多缓冲区工作方式,否则为单缓冲区方式。代码如下:

    Dim ADBuf() As Integer 'size-variable array

    Dim Working As Integer

    Dim WorkMode As Integer

    Const NumChn = 1

    Const SampPerChn = 300

    'range for iChn: 0 -- NumChn-1

    'range for iSamp: 1--SampPerChn

    Const iChn = 0

    Const iSamp = 1

    Private Sub ADCardX1_Notify()

    'event handler for multiple buffer mode

    Dim i as Long

    i = ADCardX1.GetADResult(ADBuf(0))

    If i = ADCard_Success Then

    Label1.Caption = "SeqNo=" + CStr(ADBuf(0))

    Label2.Caption = "Chn" + CStr(iChn) + ":" + CStr(ADBuf((iSamp - 1) * NumChn + iChn + 1))

    End If

    End Sub

    Private Sub Command1_Click()

    Dim i as Long

    If Working = 0 Then

    'start command

    ADCardX1.IOBase = &H110 ‘不同的AD板此参数不一样

    ADCardX1.IRQNum = 5 ‘不同的AD板此参数不一样

    ADCardX1.PhysAddr = &Hd8000 ‘不同的AD板此参数不一样

    ADCardX1.DMAChn= 5 ‘不同的AD板此参数不一样

    ADCardX1.NumInnerBuf = 1

    If WorkMode = 0 Then

    'multiple buffers mode

    ADCardX1.NumInnerBuf = 2 'range: >=1

    ADCardX1.SampPerChn = SampPerChn

    Else

    'single buffer mode

    ADCardX1.NumInnerBuf = 1 'will be set to 1 internally

    ADCardX1.SampPerChn = SampPerChn * 2

    End If

    ADCardX1.BegChn = 0

    ADCardX1.NumChn = NumChn

    ADCardX1.FrqSamp = 20000

    ADCardX1.EnableNotify = True

    If ADCardX1.Initial() = ADCard_Error Then

    Label1.Caption = "Initial Error!"

    Exit Sub

    End If

    If WorkMode = 0 Then

    If ADCardX1.StartIntr() = ADCard_Error Then

    Label1.Caption = "Start Interrupt Error!"

    Exit Sub

    End If

    Else

    If ADCardX1.StartSnapshot() = ADCard_Error Then

    Label1.Caption = "Start Snapshot Error!"

    Exit Sub

    End If

    Timer1.Interval = 20 '20 ms interval

    Timer1.Enabled = True

    End If

    ReDim ADBuf(SampPerChn * NumChn + 1)

    Working = 1

    Command1.Caption = "Stop"

    Else

    'stop command

    If WorkMode = 0 Then

    i = ADCardX1.StopIntr()

    Else

    i = ADCardX1.StopSnapshot()

    Timer1.Enabled = False

    End If

    Working = 0

    Command1.Caption = "Start"

    End If

    End Sub

    Private Sub Form_Load()

    Working = 0

    'set multiple/single buffers mode

    WorkMode = 0 '1

    End Sub

    Private Sub Timer1_Timer()

    'event handler for single buffer mode

    Dim SampPtr as Long, i as Long

    If Working = 0 Then Exit Sub

    i = ADCardX1.GetSnapshot(ADBuf(0), SampPerChn, SampPtr)

    If i = ADCard_Success Then

    Label1.Caption = "SeqNo=" + CStr(ADBuf(0))

    Label2.Caption = "Chn" + CStr(iChn) + ":" + CStr(ADBuf((iSamp - 1) * NumChn + iChn + 1))

    End If

    End Sub

    六、英文版简介

    ****************************************************************

    Readme file for ActiveX Control ADCardX:

    Beijing RBH Control Technology Corp. Ltd.

    June 1999

    Important properties:

    IOBase: Integer

    IRQNum: Integer

    PhysAddr: Long

    NumInnerBuf: Integer

    SampPerChn: Long

    BegChn: Integer

    NumChn: Integer

    FrqSamp: Long

    FrqFilter: Long

    EnableNotify: Boolean(True or False)

    ADCardName: String(Read only, displayed in control caption)

    ResultBuf: Integer(Read only at runtime)

    Visible: Integer(better set to False)

    VZero: Single

    VMax: Single

    MaxChn: Long

    MaxBinChn: Long

    Important Methods:

    ChannelFrq(ByVal NumChn As Long, ByVal FrqSamp As Long) as Single

    Initial() as integer

    StartIntr() as Long 'will return the required Buffer size(unit: byte)

    StopIntr() as Integer

    StartSnapshot() as Integer

    StopSnapshot() as Integer

    ResultBuf() as Integer

    GetADResult(ByRef ADBuf as Integer) as integer

    'Note: the Buffer size is required >=SampPerChn*NumChn+1

    GetADResultRecent(ByRef ADBuf as Integer) as integer

    'Note: the Buffer size is required >=SampPerChn*NumChn+1

    GetSnapshot(ByRef ADBuf as Integer, ByVal SampPerChn0 as Long) as Integer

    'Note: the Buffer size is required >=SampPerChn*NumChn+1

    ' and SampPerChn0 < SampPerChn

    IOCtl(ByVal InSize as Long, ByVal InBuff as String, ByVal OutSize as Long, ByVal OutBuff as String) as Long:

    IOCtlByte(ByVal InSize as Long, ByRef InBuff as Byte, ByVal OutSize as Long, ByRef OutBuff as Byte) as Long:

    InportB(ByVal Port as Integer) as Integer:

    Inport(ByVal Port as Integer) as Integer:

    InportDW(ByVal Port as Integer) as Long:

    OutportB(ByVal Port as Integer, ByVal Value as Integer):

    Outport(ByVal Port as Integer, ByVal Value as Integer):

    OutportDW(ByVal Port as Integer, ByVal Value as Long):

    Important Event:

    Notify(): called when one of AD Buffers is filled.

    (Number of filled buffers can be determined from ResultBuf)

    (This notify event occures only when activiated by StartIntr(),

    and the Property EnableNotify= true)

    Important Constant:

    ADCard_Error = 0

    ADCard_Success = 1

    Important Note:

    This ActiveX OCX need ADCard.DLL in \Windows\System directory

    and appropriaty VxD file.

    第二节 直接调用ADCard.DLL的底层编程方法

    一、概述

    第一节介绍的控件编程实际是对底层ADCard.Dll的一种易用性的封装,高级程序员实际可直接调用ADCard.Dll以实现更高的效率和灵活性,并直接应用于C/C++语言。

    对于每一个瑞博华公司的AD板,提供的Windows 95/98下的驱动程序均包括ADCardX.OCX(各板均相同)、ADCard.DLL(各板不同,但调用接口是相同的)和相应的Vxd驱动程序,使用前需把它们拷贝到Windows\System目录下。

    以上控件的各个方法实际对应ADCard.DLL的一个函数,控件的各属性实际对应ADCard.DLL各函数的参数。各参数的调用接口定义在C语言头文件ADCard.h中。现着重介绍控件未反映的DLL函数(其他函数和控件的同名方法的意义和用法相同):

    1. ConfigInfo()

    void __stdcall ConfigInfo(char * ADCard_Name,\

    int * MaxChn,\

    int * LowFreq,\

    int * HighFreq,\

    int * MinSampNum,\

    float * VZero,\

    float * VMax,\

    int * MaxBinChn);

    此函数返回AD板的配置信息,如AD板名称ADCard_Name、最大通道数MaxChn、最大开关量通道数MaxBinChn、AD板数据格式信息VMax和Vzero。

    2. RegisterNotify()

    int __stdcall RegisterNotify(UINT NotifyNo, HANDLE hWnd,UINT uMsg,\

    UINT wParam, LONG lParam);

    此函数设置或取消提示(Notify)消息,即AD板驱动程序在多缓冲区方式下每缓冲区满时,或在单缓冲区方式下每采集到NotifyLength时,将向用户程序(实际为句柄hWnd代表的窗口)发送消息(uMsg,wParam,lParam);可注册0至3号多个消息(NotifyNo=1~3),若hWnd=0或uMsg=0将屏蔽此消息。

    在控件中设置属性NotifyEnable实际就将调用此函数来注册Notify消息。

    3. QueryBuf()

    WORD __stdcall QueryBuf(void);

    此函数返回多缓冲区方式下工作的AD板已存满AD采集结果的缓冲区的数目,在控件中属性ResultBuf反映的实际就是此函数的调用结果。

    二、C语言调用方式

    为在C语言下调用DLL的各函数,在VC下,可直接调用函数名,在连接阶段直接加上库文件ADCard.LIB即可;在别的语言或VC下,也可用更直接的方法:

    //初始化

    HANDLE hDll = LoadLibrary("ADCard.DLL")) {

    Initial =(int (__stdcall *)(WORD, WORD, DWORD,WORD )) GetProcAddress(hDll, "_Initial@16");

    //调用

    (*Initial)(IOBase,IRQNum,PhysAdr,DMAChn);

    三、VB下调用方式

    在VB下,先声明如下过程:

    'dll routine

    Declare Function DllInitial Lib "adcard.dll" Alias "_Initial@16" (ByVal IOBase As Integer, ByVal IRQNum As Integer, ByVal PhysAddr As Long, ByVal DMAChn as Integer) As Long

    Declare Function DllStartIntr Lib "adcard.dll" Alias "_StartIntr@28" (ByVal NumBuf As Integer, ByVal NumSamp As Long, ByVal BegChn As Integer, ByVal NumChn As Integer, ByVal FrqSamp As Long, ByVal FrqFilter As Long, ByVal AmpGain As Integer) As Long

    Declare Function DllStartSnapshot Lib "adcard.dll" Alias "_StartSnapshot@32" (ByVal NumBuf As Integer, ByVal NumSamp As Long, ByVal BegChn As Integer, ByVal NumChn As Integer, ByVal FrqSamp As Long, ByVal FrqFilter As Long, ByVal AmpGain As Integer, ByVal NotifyLength As Long) As Long

    Declare Function DllStopIntr Lib "adcard.dll" Alias "_StopIntr@0" () As Long

    Declare Function DllRegisterNotify Lib "adcard.dll" Alias "_RegisterNotify@20" (ByVal NotifyNo As Long, ByVal hWnd As Long, ByVal uMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long

    Declare Function DllQueryBuf Lib "adcard.dll" Alias "_QueryBuf@0" () As Integer

    Declare Function DllADResult Lib "adcard.dll" Alias "_ADResult@4" (ByRef pBuf As Integer) As Long

    Declare Function DllADResultRecent Lib "adcard.dll" Alias "_ADResultRecent@4" (ByRef pBuf As Integer) As Long

    Declare Function DllGetSnapshot Lib "adcard.dll" Alias "_GetSnapshot@12" (ByRef pBuf As Integer, ByVal SampPerChn As Long, ByRef SampPtr As Long) As Long

    Declare Sub DllConfigInfo Lib "adcard.dll" Alias "_ConfigInfo@32" (ByVal ADCardName As String, ByRef MaxChn As Long, ByRef LowFrq As Long, ByRef HighFrq As Long, ByRef MinSampNum As Long, ByRef VZero As Single, ByRef VMax As Single, ByRef MaxBinChn As Long)

    Declare Function DllChannelFrq Lib "adcard.dll" Alias "_ChannelFrq@8" (ByVal NumChn As Long, ByVal FrqSamp As Long) As Single

    Declare Function DllIOCtl Lib "adcard.dll" Alias "_IOCtl@16"(ByVal InSize as Long, ByVal InBuff as String, ByVal OutSize as Long, ByVal OutBuff as String) as Long

    Declare Function DllIOCtlByte Lib "adcard.dll" Alias "_IOCtl@16"(ByVal InSize as Long, ByRef InBuff as Byte, ByVal OutSize as Long, ByRef OutBuff as Byte) as Long

     

    Declare Sub DllOutportB Lib "ADCard.dll" Alias "_outportb@8" (ByVal Port as Integer,ByVal Value as Integer)

    Declare Sub DllOutport Lib "ADCard.dll" Alias "_outport@8" (ByVal Port as Integer,ByVal Value as Integer)

    Declare Sub DllOutportDW Lib "ADCard.dll" Alias "_outportdw@8" (ByVal Port as Integer,Byal Value as Long)

    Declare Function DllInportB Lib "ADCard.dll" Alias "_inportb@4" (ByVal Port as Integer) as Integer

    Declare Function DllInport Lib "ADCard.dll" Alias "_inport@4" (ByVal Port as Integer) as Integer

    Declare Function DllInportDW Lib "ADCard.dll" Alias "_inportdw@4" (ByVal Port as Integer) as Long

    再按如下类似方式调用即可:

    DllInitial(IOBase,IRQNum,PhysAddr,DMAChn)

    第三节 Win95/98下DEMO程序说明

    一、文件列表

    DEMO 总目录

    ADCard.H ADCARD.DLL的C语言接口头文件

    ADCard.LIB VC下ADCARD.DLL的接口库文件

    CON_TEST.C VC下Console模式演示程序源文件

    TESTOCX VB 5.0下使用ADCardX控件的简单DEMO程序

    VBTEST VB 5.0下较复杂的演示程序

    CBTEST C++ Builder 3.0下功能类似于VBTEST的演示程序

    二、使用说明

    以上演示程序是可通用于各AD板的程序,故要真正在用户所使用的AD板上工作,对CON_TEST、TESTOCX要修改源程序中的AD板参数,对VBTEST、CBTEST要在程序运行的配置窗口中修改AD板参数(IOBase、IRQNum、PhysAddr等)。

    演示程序以不同的编程环境演示AD板的基本工作流程:在多缓冲区方式下,先调用Initial()函数初始化驱动程序,再调用StartIntr()函数使AD板开始工作,由ADResult()或ADResultRecent()连续不断地、一块一块地取得AD采集结果,结束时,由StopIntr()停止AD板工作。

    在单缓冲区的示波器方式下,先调用Initial()函数初始化驱动程序,再调用StartSnapshot()函数使AD板开始工作,由GetSnapshot()函数随时取得最新的一块AD采集结果,结束时,由StopIntr()停止AD板工作。



     
     
    返回 关闭窗口